xquery version "1.0";

declare namespace session="http://exist-db.org/xquery/session";
declare namespace request="http://exist-db.org/xquery/request";
declare namespace util="http://exist-db.org/xquery/util";
declare namespace i18n="http://apache.org/cocoon/i18n/2.1";

import module namespace ristenutil="http://www.risten.no/shared/util" at "../xquery/ristenutil.xqm";

(: Create filter expression from query term, field and mode,
   and add a classification filter if specified :)
declare function local:filter-expr($term  as xs:string,
                                $field as xs:string,
                                $mode  as xs:string) as xs:string
{
    (: Build the term search expression: :)
    let $f  := "l", (: This contains the element name to search, can be taken from user input :)
        $t  := concat("'", $term, "'"),  (: add single quotes around the search term :)
        $t2 := replace($term,"\?",".?"), (: replace ? with .? :)
        $t3 := replace($t2,"\*",".*"),   (: replace * with .* :)
        $t4 := replace($t3,"\(","\\("),  (: escape left parenthesis :)
        $t5 := replace($t4,"\)","\\)"),  (: escape right parenthesis :)
        $ttrad := concat("'^", $t5, "'") (: anchor the search string to each end :)

    let $termsearch :=
        if ($mode = "trad") then
            concat("matches(", $f, ", ", $ttrad, ")")
        else if ($mode = "near") then
            concat("near(", $f, ", ", $t, ")")
        else if ($mode = "exact") then
            concat($f, " = ", $t)
        else
            concat($f, " &= ", $t)

    return $termsearch
};

(: Assemble the query string :)
declare function local:build-query($srchcoll  as xs:string,
                                   $term     as xs:string,
                                   $orderby  as xs:string)
                                 as xs:string
{
    let $field := request:get-parameter("field", "any"),
        $mode  := request:get-parameter("mode", "all"),
		$expr  := local:filter-expr($term, $field, $mode)
    return
        let $query := concat("for $r in collection('",
      		        $srchcoll,
      		        "')//e[", (: adjust to the name of the element containing the dic article :)
            		$expr,
            		"] return ",
            		"<superentry nodeid='{util:node-id($r)}' ",
            		"doc='{util:document-name($r)}'>",
            		"{$r}</superentry>")
        return $query
};

(: Present an overview of query results :)
declare function local:displayHitlist($hits as node()+, $srchcoll as xs:string)
as element()
{
    let $count := count($hits),
        $max   := request:get-parameter("howmany", "10") cast as xs:int,
        $start := request:get-parameter("start", "1") cast as xs:int,
        $end   := if ($start + $max - 1 < $count) then $start + $max - 1 else $count

    return
        <query-results collection="{$srchcoll}" hits="{$count}"
            start="{$start}" next="{$end + 1}" max="{$max}">
            {
              for $p in $start to $end
              return
                let $current := item-at($hits, $p)
                return $current
            }
        </query-results>
};

(: Main function - retrieves some request and session attributes,
   forks further processing to other defined functions depending
   on the retrieved values :)
declare function local:main() as element()+
{
    let $term     := request:get-parameter("term", ""),  (: default value must be "" :)
        $srchlang := request:get-parameter("showlang","all"),
		$srchcoll := request:get-parameter("srchcoll",""), (: the ID :)
		$sort-key := "head"

	let $session-results := concat($srchcoll, "-results"),
	    $session-query   := concat($srchcoll, "-query")

	let $previous := session:get-attribute($session-results),
		$queryOld := session:get-attribute($session-query)

(: DEBUG ONLY: :)
    let $coll     := request:get-parameter("coll","all"),
		$params   := request:get-parameter-names(),
		$session  := session:get-attribute-names()

    return
        if(string-length($term) = 0) then
			if (exists($previous)) then
			(
(: DEBUG output: :)
			    <p><small>Your document path: {$srchcoll}<br/>
                Your $lang string: {$srchlang}<br/>
                Your session attributes: {$session}<br/>
                Your query filter/old query:<br/>
                {$queryOld}
                </small></p>,
                <p class="searchterm">
                <i18n:text>UrSrchTrm</i18n:text>: «{$term}»</p>
                ,
                local:displayHitlist($previous, $srchcoll)
            )
			else
				<p><i18n:text>ErrorTimeOut</i18n:text></p>
        else
	let $query := local:build-query($srchcoll, $term, $sort-key)
        
            let $hits := util:eval( $query ),
                $s := session:set-attribute($session-results, $hits),
                $u := session:set-attribute($session-query,   $query)
            return
                if (empty($hits)) then
                    (
                    <query-results collection="{$srchcoll}" hits="0"
                        start="0" next="1" max="0">
                      <i18n:text>NoHit</i18n:text> «{$term}»!
                    </query-results>
(: DEBUG only - output some extra info :)
                    ,
                    <p><small>Your document path: {$srchcoll}<br/>
					Your $lang string: {$srchlang}<br/>
					Your session attributes: {$session}<br/>
					Your query filter/old query:<br/>
					{$queryOld}<br/>
					Your complete search query:<br/>
					{$query}
					</small></p>
					)
                else (
(: DEBUG only - output some extra info :)
					<p><small>Your document path: {$srchcoll}<br/>
					Your $lang string: {$srchlang}<br/>
					Your session attributes: {$session}<br/>
					Your query filter/old query:<br/>
					{$queryOld}<br/>
					Your complete search query:<br/>
					{$query}
					</small></p>,
					<p class="searchterm">
					<i18n:text>UrSrchTrm</i18n:text>: «{$term}»</p>
					,
					local:displayHitlist($hits, $srchcoll)
					)
};

let $collelements := tokenize(request:get-parameter("srchcoll",""),'/'),
    $coll := $collelements[last()],
    $type := $collelements[last()-1]
return
  <section id="{$coll}" type="{$type}" title="coll-short:{$coll}" i18n:attr="title">
    <header>
      <style href="risten_query_dicts_kaleng_search-coll-entries.css"/>
    </header>
      { let $start := util:system-time() return
      	(
   	      local:main(),
          <p class="srchtime">
          { round-half-to-even( seconds-from-duration(
            util:system-time()-$start) , 3)}
          </p>
      	)
      }
  </section>