#include "symbols.sfst"

ALPHABET = [#sym#]

%%%%%%%%%%%%%%%%%%%%%%%%
% Epenthetic deletions %
%%%%%%%%%%%%%%%%%%%%%%%%

% moden -> modne
$contract-e$ = e:<> ^-> [#cons#]__[#lnr#]<X1><Affix-B>[ea]

% middel - midler
$cons-short-before-deletion$ = [d]:<> ^-> [d]__[#lnr#]<X1><Affix-B>[ea]

% mann -> menn, bok -> bøker, strand -> strender
$umlaut$ = (u:y|o:ø|a:e) ^-> __[#cons#]+e?<Z1>

% hare -> harer
% left context has to be [#letter#][#cons#], so the e en fe isn't deleted
$delete-schwaa$ = e:<> ^-> [#vowel#][#cons#]*?__<Affix-B>([#vowel#]|[#cons#][#cons#])

% kollega -> kolleger, konto -> konti
$delete-foreign-vowel$ = (a:<>|o:<>) ^-> [#cons#]__<X2>

% søster -> søstre
$delete-plural-consonant$ = r:<> ^-> <X1>e__

% kriterium -> kriterier, faktum -> fakta
$delete-um$ = {um}:<> ^-> [#letter#] __ <X5>

$t-weakening$ = t:d ^-> [#letter#]__<X6><Affix-B>e

%%%%%%%%%%%
% Clitics %
%%%%%%%%%%%

% huss -> hus'
$clt-s$ = {<Affix-B>s}:' ^-> s__

%%%%%%%%%
% Verbs %
%%%%%%%%%

$geminate-deletion-in-front-of-dt$ = {[lng]e}:<> ^-> __<Q3><Affix-B>[dt]

$delete-inf-e$ = e:<> ^-> __<Q3><Affix-B>

%%%%%%%%%%%%%%%%%%
% General polish %
%%%%%%%%%%%%%%%%%%

$delete-triggers$ = ([#trigger#]:<>) ^-> [#letter#]__
$delete-boundaries$ = ([#boundaries#]:<>) ^-> [#letter#]__

%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
% Final phonological transducer %
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%

$contract-e$ || \
$cons-short-before-deletion$ ||\
$umlaut$ ||\
$delete-schwaa$ ||\
$delete-foreign-vowel$ ||\
$delete-plural-consonant$ ||\
$delete-um$ ||\
$clt-s$ ||\
$t-weakening$ ||\
$geminate-deletion-in-front-of-dt$ ||\
$delete-inf-e$ ||\
$delete-triggers$ ||\
$delete-boundaries$