! =============== !
! Noun morphology !
! =============== !

!=======================!
! Simple 1. declination !
!=======================!

LEXICON tp !aġnaq ere
	tp_sing ;
	tp_du ;
	tp_pl ;

LEXICON tp_sing !erre
+QAQ:%TRUNC%>qaq	IV ;
+IT:%TRUNC%>it	IV ;
+N:%TRUNC	ObliqueCases_Sg ;
+N+ABS+SG:           clit_sing ;
+N+REL+SG:%TRUNC%>m  clit_sing ;
+N+ABS+SG+1Sg:%FRIC%>ga	clit_sing ;
+N+ABS+SG+2Sg:%TRUNC%>n	clit_sing ;
+N+ABS+SG+3Sg:%TRUNC%>a	clit_sing ; !Not verified aġnaq


LEXICON tp_du
+N+ABS+DU:%TRUNC%C%>k	clit ; 
+N:%C%>k        ObliqueCases_Du ; 
+N+ABS+DU+1Sg:%TRUNC%>kka	clit ;
+N+ABS+DU+2Sg:%TRUNC%>kiñ	clit ;
+N+ABS+DU+2Sg+Arch:%TRUNC%>kkiñ	clit ;

LEXICON tp_pl
+N+ABS+PL:%TRUNC%>t	clit ;
+N:%TRUNC	ObliqueCases_Pl ; 
+N+ABS+PL+1Sg:%TRUNC%>tka	clit ;
+N+ABS+PL+2Sg:%TRUNC%>tin	clit ;
+N+ABS+PL+3Sg:%TRUNC%>ŋi	clit ;
+N+REL+PL+3Sg:%TRUNC%>ŋisa	clit ;

!===========================!
! Geminating 1. declination !
!===========================!

LEXICON tp_gem !geminating stems of 1. declination - amaġuq nusaq/nuyaq
	tp_gem_sing ;
	tp_gem_du ;
	tp_gem_pl ;

LEXICON	tp_gem_sing
+QAQ:%TRUNC%>qaq	IV ;
+IT:%TRUNC%>it	IV ;
	ObliqueCases_Sg ;
+N+ABS+SG:           clit ;
+N+REL+SG:%TRUNC%C%>m  clit ; ! = Kal???
+N+ABS+SG+1Sg:%FRIC%>ga	clit ; !just a slotholder
+N+ABS+SG+2Sg:%TRUNC%>n	clit ; !just a slotholder

LEXICON	tp_gem_du
+N+ABS+DU:%TRUNC%DEFRIC%>k	clit ;
+N:%C%>k        ObliqueCases_Du ; 
+N+ABS+DU+1Sg:%TRUNC%>kka	clit ; !just a slotholder
+N+ABS+DU+2Sg:%TRUNC%>kiñ	clit ; !just a slotholder
+N+ABS+DU+2Sg+Arch:%TRUNC%>kkiñ	clit ; !just a slotholder

LEXICON	tp_gem_pl
+N+ABS+PL:%TRUNC%C%>t	clit ;
+N:%TRUNC%C%>t	ObliqueCases_Pl ; 
+N+ABS+PL+1Sg:%TRUNC%>tka	clit ; !just a slotholder
+N+ABS+PL+2Sg:%TRUNC%>tin	clit ; !just a slotholder


!========================!
! 1. declination in schwa!
!========================!

LEXICON tpt
	tpt_sing ;
	tpt_du ;
	tp_pl ;

LEXICON tpt_sing !aŋun:aŋute
+QAQ:%TRUNC%>qaq	IV ;
+IT:%>it	IV ;
+N:%CVCTRUNCn	ObliqueCases_Sg ;
+N+ABS+SG:%CVCTRUNCn	clit ;
+N+REL+SG:%>m	clit ;
+N+TRM+SG:%CVCTRUNCn%>mun	clit ;
+N+ABS+SG+1Sg:%FRIC%>ga	clit ; !just a slotholder
+N+ABS+SG+2Sg:%TRUNC%>n	clit ; !just a slotholder

LEXICON tpt_du
+N+ABS+DU:%EBLOCK%>k	clit ; 
+N:%EBLOCK%>k        ObliqueCases_Du ; 
+N+ABS+DU+1Sg:%TRUNC%>kka	clit ; !just a slotholder
+N+ABS+DU+2Sg:%TRUNC%>kiñ	clit ; !just a slotholder
+N+ABS+DU+2Sg+Arch:%TRUNC%>kkiñ	clit ; !just a slotholder


LEXICON tup !aiviq
+QAQ:%TRUNC%>qaq	IV ;
+IT:%SCHWADEL%>it	IV ;
+N:%>	ObliqueCases_Sg ;
+N+ABS+SG:	clit ;
+N+ABS+PL:%>%FRICit	clit ;
+N+TRM+SG:%>mun	clit ;
+N+Abl+SG:%>miñ	clit ;

LEXICON tup- !siksrik iñuk
+QAQ:%TRUNC%>qaq	IV ;
+IT:%SCHWADEL%>it	IV ;
+N+ABS+SG:	clit ;
+N+ABS+DU:%TRUNC%C%>k	clit ; 
+N+ABS+PL:%TRUNC%>it	clit ;
+N+ABS+SG+1Sg:%FRIC%>ga	clit ; 

LEXICON ObliqueCases_Sg
+LOC+SG:%>mi	clit_sing ;
+MOD+SG:%>mik	clit_sing ;
+TRM+SG:%>mun	clit_sing ;

LEXICON ObliqueCases_Du
+LOC+DU:%>ni	clit ;

LEXICON ObliqueCases_Pl
+LOC+PL:%>ni	clit ;
+TRM+PL:%>nun	clit ;


! Proper nouns ! Still a dummy
LEXICON propmorph
+N:	clit ;

! Pronouns ! Still a dummy
LEXICON pronmorph
+N:	clit ;