xquery version "1.0";

declare namespace request="http://exist-db.org/xquery/request";
declare namespace util="http://exist-db.org/xquery/util";
declare namespace i18n="http://apache.org/cocoon/i18n/2.1";

import module namespace save="http://www.risten.no/edit/save" at "xquery/saveroutines.xqm";
import module namespace ristenutil="http://www.risten.no/shared/util" 
       at "../xquery/ristenutil.xqm";

(: This function updates the ID of an entry, and all references to it :)
declare function local:updateID($oldID as xs:string, $newID as xs:string) as xs:string
{
    let $lang   := request:get-parameter("lang", ""),
        $user   := session:get-attribute("user"),
		$cntr   := "termcenter.xml",
		$doc    := ristenutil:get-doc($lang),
		$cntdoc := concat($coll,'/',$cntr)

    (: Need to use ' since $oldcenterref is used as part of an attribute already containing '' :)
    (: Also, it has to be ' and not ", since it should match a string containing '' :)
    let $oldcenterref := concat("terms-", $lang, ".xml",
	                       "#xpointer(//entry[@id='",
	                        $oldID,
	                       "'])" ),
        $newcenterref := concat("terms-", $lang, ".xml",
	                       "#xpointer(//entry[@id='",
	                        $newID,
	                       "'])" )

    (: Update the ID of the entry itself: :)
    let $mainupdate :=
      <xupdate:update
          xmlns:xupdate="http://www.xmldb.org/xupdate"
          select="doc('{$doc}')//entry/@id[. = '{$oldID}']" >{$newID}</xupdate:update>

    (: Update all references to the term in the central term records: :)
    (: Note that since $oldcenterref contains escaped '-s (&apos;), it has to be surrounded by
       double quotes, which in turn has to be within single quotes. This alternation is
       important - without it the selection will crash due to unexpected end of string!!! :)
    let $centerupdate :=
      <xupdate:update
          xmlns:xupdate="http://www.xmldb.org/xupdate"
          select='doc("{$cntdoc}")//entryref[@xml:lang = "{$lang}"]/*/@href[. = "{$oldcenterref}"]' >{
            $newcenterref
            }</xupdate:update>

    (: Update all references to the term from synonyms, orthographical variants and main terms: :)
    (: The references to be updated are in attributes:
       - mainref
       - synref
       - variantref
       and have to be targeted independently. :)
    let $refupdate := (
      <xupdate:update
          xmlns:xupdate="http://www.xmldb.org/xupdate"
                select="doc('{$doc}')//@mainref[. = '{$oldID}']" >{$newID}</xupdate:update>,
      <xupdate:update
          xmlns:xupdate="http://www.xmldb.org/xupdate"
                select="doc('{$doc}')//@synref[. = '{$oldID}']" >{$newID}</xupdate:update>,
      <xupdate:update
          xmlns:xupdate="http://www.xmldb.org/xupdate"
                select="doc('{$doc}')//@variantref[. = '{$oldID}']" >{$newID}</xupdate:update>
    )

    let $timestamp     := save:languageTimeStamp($doc)
    let $cntrtimestamp := save:centerTimeStamp($cntdoc)

    (: Wrap all update statements in the outer XUpdate element: :)
    let $xupdate :=
    <xupdate:modifications version="1.0"
      xmlns:xupdate="http://www.xmldb.org/xupdate" >
      { $mainupdate }
      { $centerupdate }
      { $refupdate }
      { $timestamp }
      { $cntrtimestamp }
    </xupdate:modifications>

    (: Execute the complete XUpdate:  :)
    let $dummy := xmldb:update($collection, $xupdate)

    return $newID
};

(: Assemble the query string :)
declare function local:build-query($record as xs:string, $entrylang as xs:string)
as xs:string
{
    let $expr := ristenutil:id-filter($record),
		$doc  := ristenutil:get-doc($entrylang)
    return
        concat("for $r in document('", $doc, "')//entry[",
            $expr, "] return $r")
};

(: Check for the existence of the new entry: :)
declare function local:ID-exists($entry as xs:string, $entrylang as xs:string)
                   as xs:boolean
{
    let $query := local:build-query($entry, $entrylang),
        $hits  := util:eval( $query ),
        $count := count($hits)
    return if ( $count = 0 ) then
             false()
           else
             true()
};

(: Main function - retrieves some request attributes,
   forks further processing to other defined functions depending
   on the retrieved values :)
declare function local:main() as element()+
{
	let $record    := request:get-parameter("id",     ""),
		$rawentry  := request:get-parameter("entry",  ""),
		$pos       := request:get-parameter("pos",    ""),
		$entry     := ristenutil:cleanEntry(    $rawentry   ),
		$entrylang := request:get-parameter("lang",   ""),
		$inputtype := request:get-parameter("common", ""),
		$newid     := concat(translate($entry,' ','_'),'\',$pos)

    let $exists    := local:ID-exists($newid, $entrylang)

    return
        if(string-length($record) = 0) then
                <p>WARNING: There was an error with this request!
                   Please check with the webmaster. <small>Cause:
                   No request record value.</small>
                </p>
        else
          if ( ( $exists ) and ($record != $newid) ) then
                <p>WARNING: You can not change the entry to an existing entry.
                   Please copy the information manually to the existing entry.
                </p>
          else
            let $updatedid := if ($record != $newid) then
                                  local:updateID($record, $newid)
                              else $record
            let $saveresult := save:saveentry($updatedid),
                $query := local:build-query($updatedid, $entrylang),
                $hits := util:eval( $query )
            return
                if (empty($hits)) then (
                    <p>ERROR! Record {$updatedid} not found!</p>,
                    <p>Your language: {$entrylang}</p>,
                    <p>Your request: {$updatedid}</p>,
                    <p>Your entry: {$entry}</p>,
                    <p><small>Your search query:<br/>
                    <query class="hidden">{$query}</query>
                    </small></p> )
                else (
(: DEBUG:           <p><small>Your search query:<br/>
                    <query class="hidden">{$query}</query>
                    </small></p>,
                    <p>The input type: {$inputtype}</p>
                    ,
                    <p>The save result: {$saveresult}</p>
                    , :)
                    ristenutil:display($entrylang, $hits)
                    )
};


<document>
	<body>
        <section title="DictTitle">
            { let $start := util:system-time(),
            		 $entrylang := request:get-parameter("lang",	"")
            		return
				(
					ristenutil:pre-main($entrylang, local:main()),
                     <p class="srchtime">
                        <i18n:translate>
                          <i18n:text>SearchTime</i18n:text>
                          <i18n:param type="number" pattern="#.##" >
                          { round-half-to-even( seconds-from-duration(
                            util:system-time()-$start) , 3)}
                          </i18n:param>
             	       </i18n:translate>
                     </p>
				)
			}
        </section>
    </body>
</document>