xquery version "1.0";

declare namespace util="http://exist-db.org/xquery/util";
declare namespace fn="http://exist-db.org/local-functions";
declare namespace i18n="http://apache.org/cocoon/i18n/2.1";

import module namespace save="http://www.risten.no/edit/save" at "saveroutines.xqm";
import module namespace ristenutil="http://www.risten.no/shared/util" 
       at "../xquery/ristenutil.xqm";

(: Assemble the query string :)
declare function fn:build-query($record as xs:string, $entrylang as xs:string)
as xs:string
{
    let $expr := ristenutil:id-filter($record),
		$doc  := ristenutil:get-doc($entrylang)
    return
        concat("for $r in document('", $doc, "')//entry[",
            $expr, "] return $r")
};

(: Check for the existence of the new entry: :)
declare function fn:ID-exists($entry as xs:string, $entrylang as xs:string)
                   as xs:boolean
{
    let $query := fn:build-query($entry, $entrylang),
        $hits  := util:eval( $query ),
        $count := count($hits)
    return if ( $count = 0 ) then
             false()
           else
             true()
};

(: Modify the query results before display:  :)
declare function fn:display($entrylang as xs:string, $hits as node()+)
as element()
{
	let $entry   := item-at($hits, 1),
		$common  := $entry/common,
		$senses  := $entry/senses,
		$id      := $entry/@id
	return
		<entry xml:lang="{$entrylang}" id="{$id}">
		{$common}
		<senses>
		{
		for $s in $entry/senses/sense
		let $status := $s/@status
		order by $status
		return <sense href="{$s/@idref}" status="{$status}" mainref="{$s/@mainref}">
		       	<topic>
					<top  id="{$s/topicClass/@top}"  />
					<mid  id="{$s/topicClass/@mid}"  />
					<botm id="{$s/topicClass/@botm}" />
		       	</topic>
		       	{
		       	if ( $s/def ) then
		       	    $s/def
		       	else (),
		       	if ( $s/synonyms ) then
		       	    $s/synonyms
		       	else ()
		       	}
		       </sense>
		}
		</senses>
		</entry>
};

(: Main function - retrieves some request attributes,
   forks further processing to other defined functions depending
   on the retrieved values :)
declare function fn:main() as element()+
{
	let $record    := request:request-parameter("id",     ""),
		$entry     := request:request-parameter("entry",  ""),
		$pos       := request:request-parameter("pos",    ""),
		$entrylang := request:request-parameter("lang",   ""),
		$inputtype := request:request-parameter("common", ""),
		$newid     := concat(translate($entry,' ','_'),'\',$pos)

    let $exists    := fn:ID-exists($newid, $entrylang)

    return
        if(string-length($record) = 0) then
                <p>WARNING: There was an error with this request!
                   Please check with the webmaster. <small>Cause:
                   No request record value.</small>
                </p>
        else
          if ( ( $exists ) and ($record != $newid) ) then
                <p>WARNING: You can not change the entry to an existing entry.
                   Please copy the information to the existing entry.
                </p>
          else
            let $updatedid := if ($record != $newid) then
                                  save:updateID($record, $newid)
                              else $record
            let $saveresult := save:saveentry($updatedid),
                $query := fn:build-query($updatedid, $entrylang),
                $hits := util:eval( $query )
            return
                if (empty($hits)) then (
                    <p>ERROR! Record {$updatedid} not found!</p>,
                    <p>Your language: {$entrylang}</p>,
                    <p>Your request: {$updatedid}</p>,
                    <p>Your entry: {$entry}</p>,
                    <p><small>Your search query:<br/>
                    <query class="hidden">{$query}</query>
                    </small></p> )
                else (
(: DEBUG:           <p><small>Your search query:<br/>
                    <query class="hidden">{$query}</query>
                    </small></p>,
                    <p>The input type: {$inputtype}</p>
                    ,
                    <p>The save result: {$saveresult}</p>
                    , :)
                    fn:display($entrylang, $hits)
                    )
};

<document>
	<body>
        <section title="DictTitle">
            { let $start := current-time() return
				(
					fn:main(),
            			<p><small>Søket tok 
                     { seconds-from-duration(current-time()-$start) }
					sekund.</small></p>
				)
			}
        </section>
    </body>
</document>