xquery version "1.0";

declare namespace util="http://exist-db.org/xquery/util";
declare namespace fn="http://exist-db.org/local-functions";
declare namespace i18n="http://apache.org/cocoon/i18n/2.1";
declare namespace xmldb="http://exist-db.org/xquery/xmldb";

import module namespace save="http://www.risten.no/edit/save" at "saveroutines.xqm";
import module namespace ristenutil="http://www.risten.no/shared/util"  at "../xquery/ristenutil.xqm";

(: Create filter expression from query term, field and mode :)
declare function fn:filter-expr($record as xs:string) as xs:string
{
    let $pos    := request:request-parameter("pos", "S"),
        $newrec := ristenutil:makeTermID($record, $pos)
    let $t      := concat("'", $newrec, "'")
    return
        concat("@id &= ", $t)
};

(: Assemble the query string :)
declare function fn:build-query($record as xs:string, $entrylang as xs:string)
as xs:string
{
    let $expr := fn:filter-expr($record),
		$doc  := ristenutil:get-doc($entrylang)
    return
        concat("for $r in document('", $doc, "')//entry[",
            $expr, "] return $r")
};


(: Check for the existence of the new entry: :)
declare function fn:check-exists($entry as xs:string, $entrylang as xs:string)
                   as xs:boolean
{
    let $query := fn:build-query($entry, $entrylang),
        $hits  := util:eval( $query ),
        $count := count($hits)
    return if ( $count = 0 ) then
             false()
           else
             true()
};

(: Modify the query results before display:  :)
declare function fn:display($entrylang as xs:string, $hits as node()+)
as element()
{
	let $entry   := item-at($hits, 1),
		$common  := $entry/common,
		$senses  := $entry/senses,
		$id      := $entry/@id
	return
		<entry xml:lang="{$entrylang}" id="{$id}">
		{$common}
		<senses>
		{
		for $s in $entry/senses/sense
		let $status := $s/@status
		order by $status
		return <sense href="{$s/@idref}" status="{$status}" mainref="{$s/@mainref}">
		       	<topic>
					<top  id="{$s/topicClass/@top}"  />
					<mid  id="{$s/topicClass/@mid}"  />
					<botm id="{$s/topicClass/@botm}" />
		       	</topic>
		       	{
		       	if ( $s/def ) then
		       	    $s/def
		       	else (),
		       	if ( $s/synonyms ) then
		       	    $s/synonyms
		       	else ()
		       	}
		       </sense>
		}
		</senses>
		</entry>
};

(: Main function - retrieves some request attributes,
   forks further processing to other defined functions depending
   on the retrieved values :)
declare function fn:main() as element()+
{
	let $entrylang := request:request-parameter("lang",   ""),
		$entry     := request:request-parameter("entry",  ""),
		$pos       := request:request-parameter("pos",    ""),
		$class     := request:request-parameter("class",  "")

    let $l := request:set-session-attribute("newreclang", $entrylang),
        $p := request:set-session-attribute("newrecpos",  $pos),
        $c := request:set-session-attribute("class",      $class)

    let $centerid := save:saveNewCenter()

    let $exists     := fn:check-exists($entry, $entrylang)

    return
        if( $exists ) then
            let $savedentry := save:saveExistingEntry($centerid),
                $query      := fn:build-query($entry, $entrylang),
                $hits       := util:eval( $query )
            return (
(:                    <p>The result: {$savedentry}</p>, :)
                    fn:display($entrylang, $hits)
                    )
        else
            let $savedentry := save:saveNewEntry($centerid),
                $query      := fn:build-query($entry, $entrylang),
                $hits       := util:eval( $query )
            return
                if (empty($hits)) then (
                    <p>ERROR! The new record {$centerid} was not found!</p>,
                    <p>Contact the webmaster!</p> )
                else (
(: DEBUG:           <p><small>Your search query:<br/>
                    <query class="hidden">{$query}</query>
                    </small></p>,
                    <p>The save result: {$saveresult}</p>
                    ,
                    <p>The article does exist: {$exists}</p>
                    , :)
                    fn:display($entrylang, $hits)
                    )
};

<document>
	<body>
        <section title="DictTitle">
            { let $start := current-time() return
				(
					fn:main(),
            			<p><small>Søket tok 
                     { seconds-from-duration(current-time()-$start) }
					sekund.</small></p>
				)
			}
        </section>
    </body>
</document>