!This file contains the following  closed parts of speech

!Pronouns
!Subjunctions
!Conjunctions
!Numerals
!Particles
!Interjections

! Pronouns
! ========


!Pointing to all the pronominal subgrops
LEXICON Pronoun
 Personal ;
 Demonstrative ;
 Reflexive ;
! Reciprocal ;
 Interrogative ;
! Relative ;
 Indefinite ;


! Personal pronouns
! -----------------

LEXICON Personal
mån+Pron+Pers+Sg1:m persproncasesg ;
mån+Pron+Pers+Du1:m persproncasedu ;
mån+Pron+Pers+Pl1:m persproncasepl ;
dån+Pron+Pers+Sg2:d persproncasesg ;
dån+Pron+Pers+Du2:d persproncasedu ;
dån+Pron+Pers+Pl2:d persproncasepl ;
sån+Pron+Pers+Sg3:s persproncasesg ;
sån+Pron+Pers+Du3:s persproncasedu ;
sån+Pron+Pers+Pl3:s persproncasepl ;

LEXICON persproncasesg
 +Nom:ån K ;
 +Nom:ånnå K ;
 +Gen:uv K ;
 +Gen:uvva K ;
 +Acc:uv K ;
 +Acc:uvva K ;
 +Ill:unji K ;
 +Ine:ujna K ;
 +Ela:ujsta K ;
 +Com:ujna K ;

LEXICON persproncasedu
 +Nom:åj K ;
 +Nom:ådja K ;
 +Gen:unnu K ;
 +Acc:unnuv K ;
 +Ill:unnuj K ;
 +Ine:unnun K ;
 +Ela:unnus K ;
 +Com:unnujn K ;

LEXICON persproncasepl
! The second entry of each oblique case is a less common form
 +Nom:ij K ;
 +Nom:idja K ;
 +Gen:ijá K ;
 +Gen:ijáj K ;
 +Acc:ijáv K ;
 +Acc:ijájt K ;
 +Ill:idjij K ;
 +Ill:ijájda K ;
 +Ine:iján K ;
 +Ine:ijájn K ;
 +Ela:ijás K ;
 +Ela:ijájs K ;
 +Com:ijájn K ;
 +Com:ijáj K ;


! Demonstrative pronouns
! ----------------------

LEXICON Demonstrative
dat+Pron+Dem:da demcas ;
dát+Pron+Dem:dá demcas ;
dát+Pron+Dem+Sg:dá dátcas ;
duot+Pron+Dem:duo demcas ;
dåt+Pron+Dem:då demcas ;
dála+Pron+Dem:dála K ;
duola+Pron+Dem:duola K ;
dåvla+Pron+Dem:dåvla K ;


LEXICON demcas
 +Sg:0 demcassg ;
 +Pl:0 demcaspl ;

LEXICON demcassg 
 +Nom:t K ;
 +Gen:n K ;
 +Acc:v K ;
 +Acc:vva K ;
 +Ill:si K ;
 +Ine:n0na K ; ! was: n'n
 +Ela:ssta K ;
 +Com:jna K ;
 +Ess:nen K ;
 +Par:t K ;
 +Abe:bdá K ;

LEXICON demcaspl
 +Nom: K ;
 +Nom:ha K ;
 :j demcasplobl ;

LEXICON demcasplobl
 +Gen: K ;
 +Acc:t K ;
 +Ill:da K ;
 +Ine:n K ;
 +Ela:s K ;
 +Ela:sta K ;
 +Com: K ;

LEXICON dátcas
 +Nom:hta K ;
 +Nom:htak K ;
 +Gen:ñga K ;
 +Acc:vga K ;
 +Ill:siga K ;
 +Ine:nnaga K ;
 +Ela:staga K ;
 +Com:jnak K ;



! Reflexive pronouns
! ------------------

LEXICON Reflexive
!Two nominative reflexives, and pointer to the rest
iesj+Pron+Refl+Sg+Nom:iesj K ;
iesj+Pron+Refl+Du+Nom:ietja K ;
iesj+Pron+Refl+Pl+Nom:ietja K ;
iesj+Pron+Refl+Sg:0 refloblsg ;
iesj+Pron+Refl+Pl:0 refloblpl ;

LEXICON refloblsg
!The V/V2 alternation due to 3rd person vocalism
!Pointing directly to 1st and 3rd person sublexica for AG & Loc.
!Pointing to exceptional Pl sublexicon for AG and Loc.
+Acc:iehtja PxV1 ;
+Gen:iehtja PxV1 ;
+Acc:ietja PxV23 ;
+Gen:ietja PxV23 ;
+Acc+PxSg1:ietjam K ;	 ! Exceptional Sg12
+Gen+PxSg1:ietjam K ;  ! Exceptional Sg12
+Ill:iehtjas PxCi ;
+Ill:allas PxCi ;
+Ine:ietjan PxCi ;
+Ela:ietjast PxCi ;
+Com:ietjajn PxCi ;

LEXICON refloblpl
+Gen:ietjaj PxCiPlstem ;
+Acc:ietjajd PxCPlstem ;
+Ine:ietjajn PxCPlstem ;
+Ela:ietjajst PxCPlstem ;
+Com:ietjajn PxCPlstem ;

LEXICON PxCiPlstem
 +PxDu1:ma K ;
 +PxDu2:da K ;
 +PxDu3:ska K ;
 +PxPl1:ma K ;
 +PxPl2:da K ;
 +PxPl3:sa K ;

LEXICON  PxCPlstem
 +PxDu1:imme K ;
 +PxDu2:ihtte K ;
 +PxDu3:iskká K ;
 +PxPl1:imme K ;
 +PxPl2:ihtte K ;
 +PxPl3:isá K ;


! Interrogative pronouns
! ----------------------

LEXICON Interrogative
mij+Pron+Interr+Sg+Nom:mij K ;
mij+Pron+Interr:ma oblintercas ;
mij+Pron+Interr+Sg+Par:mat K ;
mij+Pron+Interr+Pl:m idiosyncmij ;
guhti+Pron+Interr+Sg+Nom:guhti K ;
guhti+Pron+Interr+Sg+Nom:gut K ;
guhti+Pron+Interr:ge oblintercas ;


LEXICON oblintercas
 +Sg+Gen:n K ;
 +Sg+Acc:v K ;
 +Sg+Acc:vva K-s ;
 +Sg+Ill:nji K-s ;
 +Sg+Ela:jsta K-s ;
 +Sg+Com:jna K-s ;
 +Pl+Gen:j K ;
 +Pl+Acc:jt K ;
 +Pl+Ill:jda K-s ;
 +Pl+Ine:jna K-s ;
 +Pl+Ela:js K ;
 +Pl+Com:j K ;

LEXICON idiosyncmij
 +Acc:at  K ;
 +Gen:ejt K ; 
 +Ill:ejda K-s ;
 +Ine:ajna K-s ;
 +Ine:ajn K ;
 +Ela:ajsta K-s ;
 +Ela:ajs K ;

LEXICON K-s ! Alternative clitic lexicon
 +Clt:s # ;
 # ;


! Indefinite pronouns
! -------------------

LEXICON Indefinite

+Pron+Ind:vehi K ;



! Subjunction
! ===========

LEXICON Subjunction
ahte	Cs ;
at	Cs ;
dade	Cs ;
Danen	Cs ;
dasik	Cs ;
degu	Cs ;
desik	Cs ;
gå	Cs ;
ihka	Cs ;
juhte	Cs ;
jus	Cs ;
jut	Cs ;
men	Cs ;
nåv% gåk	Cs ;
vaj		Cs ;
valla	Cs ;
vájk	Cs ;
vájku	Cs ;
ájnat	Cs ;

LEXICON Cs 
+CS:0 # ;





! Conjunction
! ===========


LEXICON Conjunction

de		Cc ;
ja		Cc ;
jali		Cc ;
ge		Cc ;
goappátja	Cc ;
jali		Cc ;
juogu		Cc ;
vaj		Cc ;
valla		Cc ;
vájbi		Cc ;

LEXICON Cc
+CC:0 # ;


! Numerals
! ========

LEXICON Numeral

akta AKTA ;
guokta GUOKTA ;
gålmmå GÅLMMÅ ;
niellja GUOKTA ;
vihtta GÅLMMÅ ;
guhtta GÅLMMÅ ;
gietjav GIETJAV ;
gáktsa GÁKTSA ;
aktse AKTSE ;
lågev LÅGEV ;
tjuohte TJUOHTE ;

!lågenan
!låhke
!låk

LEXICON AKTA
+Num: AKTA-NIE ;
+Num:X1 AKTA-OBL ;

LEXICON AKTA-NIE
 +Sg+Nom: K ;
 +Sg+Ill:j K ;
 +Ess:n K ;

LEXICON AKTA-OBL
 +Sg+Gen: K ; 
 +Sg+Acc:v K ;
 +Sg+Ine:n K ;
 +Sg+Ela:s K ;
 +Sg+Com:jn K ;
 +Sg+Par:t K ;
 +Pl+Nom: K ;
 +Pl+Gen:j K ;
 +Pl+Acc:jt K ;
 +Pl+Ill:jda K ;
 +Pl+Ine:jn K ;
 +Pl+Ela:js K ;
 +Pl+Com:j K ;

LEXICON GUOKTA
+Num: GUOVTE- ;
+Num: GUOKTA- ;

LEXICON GUOVTE-
K ;

LEXICON GUOKTA-
K ; 

LEXICON GÅLMMÅ
+Num: K ; 

LEXICON GIETJAV
+Num: K ; 

LEXICON GÁKTSA
+Num: K ; 

LEXICON AKTSE
+Num: K ; 

LEXICON LÅGEV
+Num: K ; 

LEXICON TJUOHTE
+Num: K ; 




! Particles
! =========

LEXICON PCLE
+Pcle: # ;

LEXICON Particle
aj PCLE ;
dal PCLE ;
dat PCLE ;
de PCLE ;
gal PCLE ;
galla PCLE ;
gus PCLE ;
ham PCLE ;
juo PCLE ;
lik PCLE ;
nav PCLE ;
ga PCLE ;




! Interjections
! =============

LEXICON INTERJ
+Interj: # ;

LEXICON Interjection
hå	INTERJ ;
håj	INTERJ ;
ge	INTERJ ;
fuoj	INTERJ ;
vuoj	INTERJ ;